Επιλογή Σελίδας

Μία εταιρεία πληροφορικής προσφέρει υπολογιστές σε τιμές οι οποίες μειώνονται ανάλογα με την ποσότητα της παραγγελίας, όπως φαίνεται στον παρακάτω πίνακα:

ΠΟΣΟΤΗΤΑ ΤΙΜΗ ΜΟΝΑΔΑΣ
1-50 580
51-100 520
101-200 470
Πάνω από 200 440

Να κατασκευάσετε πρόγραμμα το οποίο:
Γ1. Να περιλαμβάνει κατάλληλο τμήμα δηλώσεων.
Μονάδες 2
Γ2. Να διαβάζει τον αριθμό υπολογιστών που έχει προς πώληση (απόθεμα), ελέγχοντας ότι δίνεται θετικός αριθμός
Μονάδες 2
Γ3. Για κάθε παραγγελία, να διαβάζει την απαιτούμενη ποσότητα και, εφόσον το απόθεμα επαρκεί για την κάλυψη της ποσότητας να εκτελεί την παραγγελία με την ποσότητα που ζητήθηκε. Αν το απόθεμα δεν επαρκεί, διατίθεται στον πελάτη το διαθέσιμο απόθεμα. Η εισαγωγή παραγγελιών τερματίζεται, όταν εξαντληθεί το απόθεμα.
Μονάδες 6
Για κάθε παραγγελία να εμφανίζει:
Γ4. το κόστος της παραγγελίας
Μονάδες 4
Γ5. το επιπλέον ποσό που θα κόστιζε η παραγγελία, εάν ο υπολογισμός γινόταν κλιμακωτά με τις τιμές που φαίνονται στον πίνακα.
Μονάδες 6

ΦΥΛΛΑΔΙΟ ΘΕΜΑΤΩΝ

ΛΥΣΗ

ΠΡΟΓΡΑΜΜΑ Θέμα_3
ΜΕΤΑΒΛΗΤΕΣ 
ΑΚΕΡΑΙΕΣ: Απόθεμα, Ποσότητα, Κόστος, Κόστος_Κλ, Διαφορά
ΑΡΧΗ 

! Γ2
ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ 
   ΔΙΑΒΑΣΕ Απόθεμα
ΜΕΧΡΙΣ_ΟΤΟΥ Απόθεμα > 0

! Γ3
ΟΣΟ Απόθεμα > 0 ΕΠΑΝΑΛΑΒΕ 
    ΔΙΑΒΑΣΕ Ποσότητα
    ΑΝ Ποσότητα > Απόθεμα ΤΟΤΕ 
       Ποσότητα <-- Απόθεμα
       Απόθεμα <-- 0
    ΑΛΛΙΩΣ 
       Απόθεμα <-- Απόθεμα - Ποσότητα
    ΤΕΛΟΣ_ΑΝ 

! Γ4 - Γ5
    ΑΝ Ποσότητα <= 50 ΤΟΤΕ 
       Κόστος <-- Ποσότητα * 580
       Κόστος_Κλ <-- Ποσότητα * 580
    ΑΛΛΙΩΣ_ΑΝ Ποσότητα <= 100 ΤΟΤΕ 
       Κόστος <-- Ποσότητα * 520
       Κόστος_Κλ <-- 50 * 580 + (Ποσότητα - 50) * 520
    ΑΛΛΙΩΣ_ΑΝ Ποσότητα <= 200 ΤΟΤΕ
       Κόστος <-- Ποσότητα * 470
       Κόστος_Κλ <-- 50 * 580 + 50 * 520 + (Ποσότητα - 100) * 470
    ΑΛΛΙΩΣ
       Κόστος <-- Ποσότητα * 440
       Κόστος_Κλ <-- 50 * 580 + 50 * 520 + 100 * 470 + (Ποσότητα - 200) * 440
    ΤΕΛΟΣ_ΑΝ 
    Διαφορά <-- Κόστος_Κλ - Κόστος
    ΓΡΑΨΕ 'Το κόστος είναι: ', Κόστος
    ΓΡΑΨΕ 'Η διαφορά της απλής χρέωσης από την κλιμακωτή είναι: ', Διαφορά
ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ 
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
Share This