Επιλογή Σελίδας

Λύσεις – Πανελλαδικές Επαναληπτικές, Ημερήσια Λύκεια, 2010 (ΑΕΠΠ)

ΘΕΜΑ Γ

Ένα σύστημα υπολογιστή χρησιμοποιεί για τον έλεγχο πρόσβασης των χρηστών του έναν πίνακα 1000 γραμμών και 3 στηλών με τα στοιχεία τους. Σε κάθε γραμμή του αποθηκεύει, στην πρώτη στήλη το όνομα πρόσβασης του χρήστη, στη δεύτερη στήλη το συνθηματικό του και στην τρίτη έναν από τους χαρακτήρες «Σ» ή «Α». (Ο χαρακτήρας «Σ» δηλώνει ότι το συνθηματικό συνεχίζει να ισχύει, ενώ ο χαρακτήρας «Α» δηλώνει ότι το συνθηματικό πρέπει να αλλάξει).

Θεωρήστε ότι υπάρχει ένα κύριο πρόγραμμα που υλοποιεί τα παραπάνω και καλεί τη διαδικασία ΕΛΕΓΧΟΣ η οποία ελέγχει την πρόσβαση του χρήστη στο σύστημα. Να γράψετε τη διαδικασία ΕΛΕΓΧΟΣ η οποία να περιλαμβάνει:

Γ1. Τμήμα δηλώσεων.

Μονάδες 2

Κύριο τμήμα το οποίο:

Γ2. Διαβάζει το όνομα και το συνθηματικό του χρήστη. Ελέγχει αν το όνομα πρόσβασης και το συνθηματικό είναι έγκυρα, δηλαδή υπάρχουν στον πίνακα χρηστών και αναφέρονται στον ίδιο χρήστη. Αν υπάρχουν, εμφανίζει το μήνυμα «ΚΑΛΩΣ ΗΡΘΑΤΕ», διαφορετικά εμφανίζει το μήνυμα «ΛΑΘΟΣ ΟΝΟΜΑ ΠΡΟΣΒΑΣΗΣ Ή ΣΥΝΘΗΜΑΤΙΚΟ» και ζητά εκ νέου την εισαγωγή των δύο αυτών στοιχείων (ονόματος πρόσβασης και συνθηματικού) μέχρι να δοθούν έγκυρα στοιχεία.

Μονάδες 8

Γ3. Μετά την εμφάνιση του μηνύματος «ΚΑΛΩΣ ΗΡΘΑΤΕ» ελέγχει αν το συνθηματικό χρειάζεται αλλαγή. Αν χρειάζεται, ζητά από τον χρήστη την εισαγωγή νέου συνθηματικού δύο φορές (η δεύτερη ως επιβεβαίωση) μέχρις ότου το συνθηματικό και η επιβεβαίωσή του ταυτιστούν. Όταν ταυτιστούν, η διαδικασία αντικαθιστά το παλιό συνθηματικό με το νέο και τον αντίστοιχο χαρακτήρα «Α» της τρίτης στήλης με το «Σ».

Μονάδες 10

Τα θέματα σε pdf, 2010, Επαναληπτικές, Ημερήσια

ΛΥΣΗ

ΘΕΜΑ_Γ_2010_ΕΠΑΝ_ΗΜΕΡ [δεδομένα_για_20_εγγραφές]

ΠΡΟΓΡΑΜΜΑ ΘΕΜΑ_Γ_2010_ΕΠΑΝ_ΗΜΕΡ
ΣΤΑΘΕΡΕΣ
  ΕΓΓΡΑΦΕΣ=20   ! 20 Εγγραφές για τα demo δεδομένα, 1000 για την άσκηση
                ! Η σταθερά ΕΓΓΡΑΦΕΣ δηλώνεται και στο υποπρόγραμμα.
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i
  ΧΑΡΑΚΤΗΡΕΣ: x[ΕΓΓΡΑΦΕΣ,3]
ΑΡΧΗ
! Εισαγωγή δεδομένων για την εκτέλεση του προγράμματος στη ΓλωσσοΜάθεια
  !Ονόματα
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΕΓΓΡΑΦΕΣ
    ΔΙΑΒΑΣΕ x[i,1]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  !Συνθηματικά
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΕΓΓΡΑΦΕΣ
    ΔΙΑΒΑΣΕ x[i,2]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  !Α ή Σ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΕΓΓΡΑΦΕΣ
    ΔΙΑΒΑΣΕ x[i,3]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΚΑΛΕΣΕ ΕΛΕΓΧΟΣ(x)
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

ΔΙΑΔΙΚΑΣΙΑ ΕΛΕΓΧΟΣ(Χ)
ΣΤΑΘΕΡΕΣ
  ΕΓΓΡΑΦΕΣ=20
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Χ[ΕΓΓΡΑΦΕΣ, 3], ΟΝ, ΣΥΝΘ, Νέο1, Νέο2
  ΑΚΕΡΑΙΕΣ: εγγραφή, i
  ΛΟΓΙΚΕΣ: βρέθηκε
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΔΙΑΒΑΣΕ ΟΝ
    ΔΙΑΒΑΣΕ ΣΥΝΘ
    βρέθηκε <-- ΨΕΥΔΗΣ
    i <-- 1
    ΟΣΟ (i <= ΕΓΓΡΑΦΕΣ) ΚΑΙ (βρέθηκε = ΨΕΥΔΗΣ) ΕΠΑΝΑΛΑΒΕ
      ΑΝ (Χ[i, 1] = ΟΝ) ΚΑΙ (Χ[i, 2] = ΣΥΝΘ) ΤΟΤΕ
        βρέθηκε <-- ΑΛΗΘΗΣ
        εγγραφή <-- i
      ΑΛΛΙΩΣ
        i <-- i+1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΑΝ βρέθηκε = ΨΕΥΔΗΣ ΤΟΤΕ
      ΓΡΑΨΕ 'ΛΑΘΟΣ ΟΝΟΜΑ ΠΡΟΣΒΑΣΗΣ Ή ΣΥΝΘΗΜΑΤΙΚΟ'
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ βρέθηκε = ΑΛΗΘΗΣ
  ΓΡΑΨΕ 'ΚΑΛΩΣ ΗΡΘΑΤΕ'
  ΑΝ Χ[εγγραφή, 3] = 'Α' ΤΟΤΕ
    ΓΡΑΨΕ 'ο κωδικός σας έχει λήξει'
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ 'πληκτρολογήστε νέο κωδικό'
      ΔΙΑΒΑΣΕ Νέο1
      ΓΡΑΨΕ 'πληκτρολογήστε ξανά τον κωδικό'
      ΔΙΑΒΑΣΕ Νέο2
    ΜΕΧΡΙΣ_ΟΤΟΥ Νέο1 = Νέο2
    Χ[εγγραφή, 2] <-- Νέο1
    Χ[εγγραφή, 3] <-- 'Σ'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΘΕΜΑ Δ

Ερευνητές που ασχολούνται με μοντέλα προσομοίωσης εξάπλωσης επιδημιών χρησιμοποιούν για τις μελέτες τους ένα αριθμητικό πίνακα Μ[5000]. Κάθε κελί του πίνακα αυτού αντιπροσωπεύει ένα άτομο σε μια περιοχή 5.000 κατοίκων στην οποία υπάρχουν εστίες μιας συγκεκριμένης μολυσματικής ασθένειας (επιδημίας). Από σύμβαση η τιμή μηδέν 0 σε ένα κελί αντιπροσωπεύει ένα υγιές άτομο, ενώ η τιμή -1 αντιπροσωπεύει ένα άτομο που έχει τη συγκεκριμένη ασθένεια (μολυσμένο άτομο). Κάθε άτομο έρχεται σε επαφή με τα γειτονικά του και η ασθένεια μπορεί να μεταδοθεί από τον ένα στον άλλο. (Γειτονικά χαρακτηρίζονται δύο άτομα, όταν τα κελιά του πίνακα που τα αντιπροσωπεύουν έχουν μια κοινή πλευρά).

Θεωρήστε ότι δίνεται ο πίνακας Μ που περιέχει ήδη έναν αριθμό μολυσμένων ατόμων. Να υλοποιήσετε αλγόριθμο ο οποίος:

Δ1. Υπολογίζει και εμφανίζει με κατάλληλο μήνυμα τον συνολικό αριθμό των μολυσμένων ατόμων που υπάρχουν στο σύνολο του πληθυσμού.

Μονάδες 4

Δ2. Αποθηκεύει σε κάθε κελί του πίνακα Μ που αντιπροσωπεύει ένα υγιές άτομο έναν αριθμό ο οποίος δείχνει με πόσα μολυσμένα άτομα γειτονεύει το υγιές.

Μονάδες 8

Δ3. Βρίσκει αν υπάρχει έστω και μία «σημαντική» εστία μόλυνσης. Αν υπάρχει, εμφανίζει το μήνυμα «Υπάρχει σημαντική εστία μόλυνσης» μαζί με τη θέση του πρώτου κελιού της εστίας. Αν δεν υπάρχει, εμφανίζει το μήνυμα «∆εν υπάρχει σημαντική εστία μόλυνσης». (Μια εστία μόλυνσης χαρακτηρίζεται σημαντική, όταν δύο ή περισσότερα μολυσμένα άτομα βρίσκονται σε συνεχόμενα γειτονικά κελιά).

Μονάδες 8

Τα θέματα σε pdf, 2010, Επαναληπτικές, Ημερήσια

ΛΥΣΗ

ΘΕΜΑ_Δ_2010_ΕΠΑΝ_ΗΜΕΡ [demo_δεδομένα_πληθυσμός_50]

ΠΡΟΓΡΑΜΜΑ  θΕΜΑ_Δ_2010_ΕΠΑΝ_ΗΜΕΡ
ΣΤΑΘΕΡΕΣ
  ΠΛΗΘΥΣΜΟΣ=50  ! Για τα demo Δεδομένα, 500000 για την άσκηση
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Μ[ΠΛΗΘΥΣΜΟΣ], i, μολυσμένοι, πλήθος, θέση
  ΛΟΓΙΚΕΣ: βρέθηκε
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΥΣΜΟΣ
    ΔΙΑΒΑΣΕ Μ[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  Μολυσμένοι <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ ΠΛΗΘΥΣΜΟΣ
    ΑΝ Μ[i] = -1 ΤΟΤΕ
      Μολυσμένοι <-- Μολυσμένοι + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Πλήθος μολυσμένων ατόμων :', Μολυσμένοι
! ΓΙΑ το πρώτο κελί που γειτονεύει μόνο δεξιά
  ΑΝ  Μ[1] = 0 ΤΟΤΕ
    ΑΝ Μ[2] = -1 ΤΟΤΕ
      Μ[1] <-- 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ ΠΛΗΘΥΣΜΟΣ-1
    ΑΝ Μ[i] = 0 ΤΟΤΕ
      ΑΝ Μ[i-1] = -1 ΤΟΤΕ
        Μ[i] <-- Μ[i]+1
      ΤΕΛΟΣ_ΑΝ
      ΑΝ Μ[i+1] = -1 ΤΟΤΕ
        Μ[i] <-- Μ[i]+1
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
 ! ΓΙΑ το τελευταίο κελί που γειτονεύει μόνο αριστερά
  ΑΝ Μ[ΠΛΗΘΥΣΜΟΣ] = 0 ΤΟΤΕ
    ΑΝ Μ[ΠΛΗΘΥΣΜΟΣ-1] = -1 ΤΟΤΕ
      Μ[ΠΛΗΘΥΣΜΟΣ] <-- 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ
  πλήθος <-- 0
  βρέθηκε <-- ΨΕΥΔΗΣ
  i <-- 1
  ΟΣΟ (i <= ΠΛΗΘΥΣΜΟΣ) ΚΑΙ (βρέθηκε = Ψευδής) ΕΠΑΝΑΛΑΒΕ
    ΑΝ Μ[i] = -1 ΤΟΤΕ
      πλήθος <-- πλήθος + 1
    ΑΛΛΙΩΣ
      πλήθος <-- 0
    ΤΕΛΟΣ_ΑΝ
    ΑΝ πλήθος = 2 ΤΟΤΕ
      βρέθηκε <-- Αληθής
      θέση <-- i-1
    ΤΕΛΟΣ_ΑΝ
    i <-- i + 1
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΝ βρέθηκε = Αληθής ΤΟΤΕ
    ΓΡΑΨΕ  'Υπάρχει σημΑΝτική εστία μόλυνσης', θέση
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπάρχει σημΑΝτική εστία μόλυνσης'
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
Share This